YF-S201 霍爾水流量感測器 水流量傳感器 4分G1/2接口 水流計
水流量傳感器原理簡介:
1.組成:塑料閥體 、水流轉子組件和霍爾傳感器
2.裝在進水端,用於檢測進水流量
3.當水通過水流轉子,隨著流量快慢,推動磁性轉子轉動的轉速,
觸發霍爾傳感器輸出相應脈衝信號,反饋給控制器或開發板
判斷水流量的大小,進行水量檢測調控
適用範圍:適用於抽水機 熱水器,自動售水機等流量計量設備
1.工作電壓範圍DC 5∼18 V
2.最大工作電流 15 mA(DC 5V)
負載能力 ≤10 mA(DC 5V)
3.使用溫度範圍 工作溫度 :-25∼+ 80℃
4.使用濕度範圍 35%∼90%RH(無結霜狀態)
5.允許耐壓 水壓1.75Mpa以下
6.流量計算
(即頻率 脈衝數) F= 常數7.5 * 單位流量(L/min) * 時間(秒)
例:一分鐘流過1升水 輸出的 脈衝個數計算
7.5 * 1 * 60 =450, 流完一升水輸出450個脈衝
7.可測流量範圍:1∼30公升/分鐘
8.水管接口:標準 G1/2螺牙 1/2吋,外徑0.78”,螺紋1/2“
9.機體尺寸約 2.5x 1.4x 1.4寸
10.電線長度:15公分
11.輸出訊號類型:5V TTL
12.傳感器類型:霍爾效應
13.淨重 約47公克
使用注意事項:
嚴禁劇烈衝擊以及化學物質的侵蝕。
嚴禁拋擲或碰撞。
介質溫度不宜超過120度
接線方式:
紅 IN :正極
黃 OUT :PWM 類比訊號輸出線
黑 GND :負極
出貨內容:水流量傳感器 x 一個 塑膠袋包裝
範例程式:
/*
Liquid flow rate sensor -DIYhacking.com Arvind Sanjeev
Measure the liquid/water flow rate using this code.
Connect Vcc and Gnd of sensor to arduino, and the
signal line to arduino digital pin 2.
*/
byte statusLed = 13;
byte sensorInterrupt = 0; // 0 = digital pin 2
byte sensorPin = 2;
// The hall-effect flow sensor outputs approximately 4.5 pulses per second per
// litre/minute of flow.
float calibrationFactor = 4.5;
volatile byte pulseCount;
float flowRate;
unsigned int flowMilliLitres;
unsigned long totalMilliLitres;
unsigned long oldTime;
void setup()
{
// Initialize a serial connection for reporting values to the host
Serial.begin(9600);
// Set up the status LED line as an output
pinMode(statusLed, OUTPUT);
digitalWrite(statusLed, HIGH); // We have an active-low LED attached
pinMode(sensorPin, INPUT);
digitalWrite(sensorPin, HIGH);
pulseCount = 0;
flowRate = 0.0;
flowMilliLitres = 0;
totalMilliLitres = 0;
oldTime = 0;
// The Hall-effect sensor is connected to pin 2 which uses interrupt 0.
// Configured to trigger on a FALLING state change (transition from HIGH
// state to LOW state)
attachInterrupt(sensorInterrupt, pulseCounter, FALLING);
}
/**
* Main program loop
*/
void loop()
{
if((millis() - oldTime) > 1000) // Only process counters once per second
{
// Disable the interrupt while calculating flow rate and sending the value to
// the host
detachInterrupt(sensorInterrupt);
// Because this loop may not complete in exactly 1 second intervals we calculate
// the number of milliseconds that have passed since the last execution and use
// that to scale the output. We also apply the calibrationFactor to scale the output
// based on the number of pulses per second per units of measure (litres/minute in
// this case) coming from the sensor.
flowRate = ((1000.0 / (millis() - oldTime)) * pulseCount) / calibrationFactor;
// Note the time this processing pass was executed. Note that because we've
// disabled interrupts the millis() function won't actually be incrementing right
// at this point, but it will still return the value it was set to just before
// interrupts went away.
oldTime = millis();
// Divide the flow rate in litres/minute by 60 to determine how many litres have
// passed through the sensor in this 1 second interval, then multiply by 1000 to
// convert to millilitres.
flowMilliLitres = (flowRate / 60) * 1000;
// Add the millilitres passed in this second to the cumulative total
totalMilliLitres += flowMilliLitres;
unsigned int frac;
// Print the flow rate for this second in litres / minute
Serial.print("Flow rate: ");
Serial.print(int(flowRate)); // Print the integer part of the variable
Serial.print("L/min");
Serial.print("\t"); // Print tab space
// Print the cumulative total of litres flowed since starting
Serial.print("Output Liquid Quantity: ");
Serial.print(totalMilliLitres);
Serial.println("mL");
Serial.print("\t"); // Print tab space
Serial.print(totalMilliLitres/1000);
Serial.print("L");
// Reset the pulse counter so we can start incrementing again
pulseCount = 0;
// Enable the interrupt again now that we've finished sending output
attachInterrupt(sensorInterrupt, pulseCounter, FALLING);
}
}
/*
Insterrupt Service Routine
*/
void pulseCounter()
{
// Increment the pulse counter
pulseCount++;
}